1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

#-------------------------------------------------
#
# Project created by QtCreator 2013-05-22T18:40:30
#
#-------------------------------------------------

QT       += core gui network
greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TARGET = media-u
TEMPLATE = app

CONFIG += c++11
QMAKE_CXXFLAGS += -std=c++11

include(libs.pri)
include(data.pri)
include(filesystem.pri)
include(utils.pri)
include(videoutils.pri)
include(gui.pri)
include(online.pri)
include(player.pri)
include(server.pri)

SOURCES += main.cpp

# install path madness

isEmpty(PREFIX) {
    PREFIXDIR = /usr/local
} else {
    PREFIXDIR = $${PREFIX}
}
isEmpty(BINDIR):BINDIR = $${PREFIXDIR}/bin
isEmpty(SHAREDIR):SHAREDIR = $${PREFIXDIR}/share/media-u
isEmpty(SERVERDIR):SERVERDIR = $${SHAREDIR}/public

!isEmpty(PREFIX) {
    DEFINES += SERVER_PUBLIC_ROOT=\\\"$${SERVERDIR}\\\"
}

target.path = $$BINDIR
serverfiles.path = $$SERVERDIR
serverfiles.files = public/*

INSTALLS = target serverfiles